Tracking Users, Page Views by the Day Example

Then use the following to refer to your stats throughout your site:

 <% = Application("ActiveUsers") %>
<% = Application("TotalSessions") %>
<% = Application("TodaySessions") %>

This is what the global.asa should look like:

<SCRIPT LANGUAGE="VBScript" RUNAT="Server">

On Error Resume Next

Sub Application_OnStart
Application("ActiveUsers") = 0
End Sub

Sub Session_OnStart
Dim SQL
Dim RS
Dim oConn
Dim TotalSessions
Dim TodaySessions
Dim DBDriver
Dim DBPath
Dim DBUser
Dim DBPass

DBDriver = "Microsoft Access Driver (*.mdb)"
DBPath = Server.Mappath("/ADIRECTORY/TOTHEDATABASE.mdb")
DBUser = ""
DBPass = ""

Set oConn = Server.CreateObject("ADODB.Connection")
oConn.Open "DRIVER={" & DBDriver & "}; DBQ=" & DBPath, DBUser, DBPass

' Get total number of sessions for today
SQL = "Select Sessions From Sessions Where TrackDate = #" & Date() & "#"
Set RS = oConn.Execute(SQL)

' If no recorde for today was found, we need to add a new record
' and if a record was found, we increment the value and store
' it back to the database
If RS.EOF Then
  NewTotal = 1
  SQL = "Insert Into Sessions (TrackDate, Sessions) "
  SQL = SQL & "Values ('" & Date() & "', " & NewTotal & ")"
Else
  NewTotal = CInt(RS("Sessions")) + 1
  SQL = "Update Sessions Set Sessions = " & NewTotal & " "
  SQL = SQL & "Where TrackDate = #" & Date() & "#"
End If

Set RS = Nothing

oConn.Execute(SQL)

' Get total number of session since database created
SQL = "Select Sum(Sessions) As TotalSessions From Sessions"
Set RS = oConn.Execute(SQL)
TotalSessions = RS("TotalSessions")
Set RS = Nothing

' Get total number of sessions for today
SQL = "Select Sessions From Sessions "
SQL = SQL & "Where TrackDate = #" & Date() & "#"
Set RS = oConn.Execute(SQL)
TodaySessions = RS("Sessions")
Set RS = Nothing

oConn.Close
Set oConn = Nothing

Session.Timeout = 5
Session("Start") = Now

' Assign all of my application variables
Application.Lock
  Application("TotalSessions") = TotalSessions
  Application("TodaySessions") = TodaySessions
  Application("ActiveUsers") = Application("ActiveUsers") + 1
Application.Unlock
End Sub

Sub Session_OnEnd
' Remove user who is no longer on site
Application.Lock
  Application("ActiveUsers") = Application("ActiveUsers") - 1
Application.UnLock
End Sub

</SCRIPT>